NAME MSGMm0mx 'Test M1,M2 as restriction of M0';
?********************************************************************

? Replication file 2/11 for "Are Sports Teams Multiproduct Firms?"
? by K.G. Stewart and J.C.H. Jones (2010) Empirical Economics 39 (2),
? 487-514.

? Estimation of two-output MSGM factor demand system for baseball
? player characteristics, the model M0, without concavity imposed.

? TSP converges for the non-concavity-constrained 2-output model.
? Use this to perform LR and Wald tests of various restrictions, 
? examining the sensitivity of the Wald tests to heteroskedasticity-
? robust variants.

? Here we test restriction of M0 to the single output models M1 or M2
? as reported in the first two lines of Table 2.
? 1. M0 restricted to M1 (single output=y1=wins)
? 2. M0 restricted to M2 (single output=y2=road attendance)
? Choose 1 or 2 by alternating assignment of the output measures 
? below

?******************************************************************** 

SMPL 1 156; ? Sample consists of 26 teams x 6 seasons (1986-91) 

? Read in team characteristics; documented in Team.doc
read(file='Team.dat') season team league attend attlag ticprice 
pmarkup gameswon gameslst wins salaries nplayers strkouts walks 
slugavg nhitters npitchrs experhit experpit nstars roadatt
aleast alcentrl alwest nleast nlcentrl nlwest;
? Delete variables not used in this analysis
delete season team league attlag ticprice pmarkup gameswon gameslst 
salaries nplayers;

? read in hedonic prices
read(file='HedPrice1.dat') p1 p2 p3 p4 nobs;

? define team outputs; alternate assignment appropriately to set 
? M1 or M2 as restricted model in Wald tests
GENR Y1=WINS;              ? reverse this assignment
GENR Y2=roadatt/100000000; ? as needed

? define output for single-output model
genr y=y1;                 ? leave unchanged

? conference dummies
genr dum1=aleast;
genr dum2=alcentrl;
genr dum3=alwest;
genr dum4=nleast;
genr dum5=nlcentrl;

? define team factor inputs: experience, hitting, pitching, stars
GENR q1=experhit+experpit;
GENR q2=nhitters*slugavg;
GENR q3=npitchrs*strkouts/walks;
GENR q4=nstars;

? DEFLATE HEDONIC PRICES TO 1991 DOLLARS
SMPL 1 26;   
GENR p1=p1*135.0/109.6;
GENR p2=p2*135.0/109.6;
GENR p3=p3*135.0/109.6;
GENR p4=p4*135.0/109.6;
SMPL 27 52;
GENR p1=p1*135.0/113.6;
GENR p2=p2*135.0/113.6;
GENR p3=p3*135.0/113.6;
GENR p4=p4*135.0/113.6;
SMPL 53 78;
GENR p1=p1*135.0/118.3;
GENR p2=p2*135.0/118.3;
GENR p3=p3*135.0/118.3;
GENR p4=p4*135.0/118.3;
SMPL 79 104;
GENR p1=p1*135.0/124.0;
GENR p2=p2*135.0/124.0;
GENR p3=p3*135.0/124.0;
GENR p4=p4*135.0/124.0;
SMPL 105 130;
GENR p1=p1*135.0/130.7;
GENR p2=p2*135.0/130.7;
GENR p3=p3*135.0/130.7;
GENR p4=p4*135.0/130.7;

SMPL 1 156;

? Generate cost identity and cost shares 
? (This synthetic (hedonic) cost series is used 
? only for descriptive purposes in calculating the implied cost
? shares, not in estimation of cost function parameters.
? It can be compared with fitted
? cost series predicted by estimated model.)
GENR COST=p1*q1+p2*q2+p3*q3+p4*q4;
GENR S1=p1*q1/COST;
GENR S2=p2*q2/COST;
GENR S3=p3*q3/COST;
GENR S4=p4*q4/COST;

? set thetas to mean levels of factor inputs
MSD Q1; SET qm1=@MEAN;  ? qm1=135.73077
MSD Q2; SET qm2=@MEAN;  ? qm2=5.35117  
MSD Q3; SET qm3=@MEAN;  ? qm3=17.92278 
MSD Q4; SET qm4=@MEAN;  ? qm4=2.61538  

GENR DENOM=qm1*p1+qm2*p2+qm3*p3+qm4*p4;

SET THETA1=qm1/2;
SET THETA2=qm2/2;
SET THETA3=qm3/2;
SET THETA4=qm4/2;

? generate price constructs used in estimation

GENR Pd1=p1/DENOM;
GENR Pd2=p2/DENOM;
GENR Pd3=p3/DENOM;
GENR Pd4=p4/DENOM;

GENR Pd11=pd1*pd1;
GENR Pd12=pd1*pd2;
GENR Pd13=pd1*pd3;
GENR Pd14=pd1*pd4;
GENR Pd21=pd2*pd1;
GENR Pd22=pd2*pd2;
GENR Pd23=pd2*pd3;
GENR Pd24=pd2*pd4;
GENR Pd31=pd3*pd1;
GENR Pd32=pd3*pd2;
GENR Pd33=pd3*pd3;
GENR Pd34=pd3*pd4;
GENR Pd41=pd4*pd1;
GENR Pd42=pd4*pd2;
GENR Pd43=pd4*pd3;
GENR Pd44=pd4*pd4;

GENR P11=Pd11-Pd14-(Pd41-Pd44);
GENR P12=Pd12-Pd14-(Pd42-Pd44);
GENR P13=Pd13-Pd14-(Pd43-Pd44);
GENR P21=Pd21-Pd24-(Pd41-Pd44);
GENR P22=Pd22-Pd24-(Pd42-Pd44);
GENR P23=Pd23-Pd24-(Pd43-Pd44);
GENR P31=Pd31-Pd34-(Pd41-Pd44);
GENR P32=Pd32-Pd34-(Pd42-Pd44);
GENR P33=Pd33-Pd34-(Pd43-Pd44);

GENR P12=2*P12;
GENR P13=2*P13;
GENR P23=2*P23;

GENR Pd1=Pd1-Pd4;
GENR Pd2=Pd2-Pd4;
GENR Pd3=Pd3-Pd4;

PARAM S11 S12 S13 B11 B1 LAMBDA1 d11 d12 d13 d14 d15;
PARAM     S22 S23 B22 B2 LAMBDA2 d21 d22 d23 d24 d25;
PARAM         S33 B33 B3 LAMBDA3 d31 d32 d33 d34 d35;
PARAM             B44 B4 LAMBDA4 d41 d42 d43 d44 d45;
param beta d1 d2;

? Specify the SGM system: 41 parameters
FRML E1 Q1=(S11*Pd1+S12*Pd2+S13*Pd3
          -THETA1*(S11*P11+S12*P12+S13*P13
                          +S22*P22+S23*P23
                                  +S33*P33))*(Y1+BETA*Y2)
     +d11*dum1+d12*dum2+d13*dum3+d14*dum4+d15*dum5  
     +B11*(Y1+BETA*Y2)+B1+LAMBDA1*(Y1*Y1+2*D1*Y1*Y2+D2*Y2*Y2);
FRML E2 Q2=(S12*Pd1+S22*Pd2+S23*Pd3
          -THETA2*(S11*P11+S12*P12+S13*P13
                          +S22*P22+S23*P23
                                  +S33*P33))*(Y1+BETA*Y2)
     +d21*dum1+d22*dum2+d23*dum3+d24*dum4+d25*dum5     
     +B22*(Y1+BETA*Y2)+B2+LAMBDA2*(Y1*Y1+2*D1*Y1*Y2+D2*Y2*Y2);
FRML E3 Q3=(S13*Pd1+S23*Pd2+S33*Pd3
          -THETA3*(S11*P11+S12*P12+S13*P13
                          +S22*P22+S23*P23
                                  +S33*P33))*(Y1+BETA*Y2)
     +d31*dum1+d32*dum2+d33*dum3+d34*dum4+d35*dum5  
     +B33*(Y1+BETA*Y2)+B3+LAMBDA3*(Y1*Y1+2*D1*Y1*Y2+D2*Y2*Y2);
FRML E4 Q4=-((S11+S12+S13)*Pd1+(S12+S22+S23)*Pd2+(S13+S23+S33)*Pd3
           +THETA4*(S11*P11+S12*P12+S13*P13
                           +S22*P22+S23*P23
                                   +S33*P33))*(Y1+BETA*Y2)
     +d41*dum1+d42*dum2+d43*dum3+d44*dum4+d45*dum5    
     +B44*(Y1+BETA*Y2)+B4+LAMBDA4*(Y1*Y1+2*D1*Y1*Y2+D2*Y2*Y2);
     
? Restrictions yielding the single-output model: beta=d1=d2=0
frml c1 d1;
frml c2 d2;
frml c3 beta;

? Benchmark estimation with Wald test of separability
LSQ(MAXIT=500,TOL=0.0001) E1 E2 E3 E4;
set loglu=@logl;
analyz c1 c2 c3;

? With HET option
LSQ(MAXIT=200,TOL=0.0001,het) E1 E2 E3 E4;
analyz c1 c2 c3;

? Estimate the restricted model

FRML E1 Q1=(S11*Pd1+S12*Pd2+S13*Pd3+B11
          -THETA1*(S11*P11+S12*P12+S13*P13
                          +S22*P22+S23*P23
                                  +S33*P33))*Y
          +d11*dum1+d12*dum2+d13*dum3+d14*dum4+d15*dum5   
          +B1+LAMBDA1*Y1*Y1;
FRML E2 Q2=(S12*Pd1+S22*Pd2+S23*Pd3+B22
          -THETA2*(S11*P11+S12*P12+S13*P13
                          +S22*P22+S23*P23
                                  +S33*P33))*Y
          +d21*dum1+d22*dum2+d23*dum3+d24*dum4+d25*dum5  
          +B2+LAMBDA2*Y1*Y1;
FRML E3 Q3=(S13*Pd1+S23*Pd2+S33*Pd3+B33
          -THETA3*(S11*P11+S12*P12+S13*P13
                          +S22*P22+S23*P23
                                  +S33*P33))*Y
          +d31*dum1+d32*dum2+d33*dum3+d34*dum4+d35*dum5
          +B3+LAMBDA3*Y1*Y1;
FRML E4 Q4=-((S11+S12+S13)*Pd1+(S12+S22+S23)*Pd2+(S13+S23+S33)*Pd3
          +B44 
          +THETA4*(S11*P11+S12*P12+S13*P13
                          +S22*P22+S23*P23
                                  +S33*P33))*Y
          +d41*dum1+d42*dum2+d43*dum3+d44*dum4+d45*dum5   
          +B4+LAMBDA4*Y1*Y1;
LSQ(MAXIT=200,TOL=0.0001) E1 E2 E3 E4;
set loglr=@logl;

set LR=2*(loglu-loglr);
print loglu loglr;
CDF(chisq,df=3) LR;

end;