name REStat '3-equation model of league conduct';
?*****************************************************************              
?*                                                               *   
?*  Replication file for the 3-equation model of                 *
?*  Ferguson, Jones, & Stewart (August 2000)                     *  
?*  "Competition within a cartel: League conduct and team        *  
?*  conduct in the market for baseball player services,"         *  
?*  Review of Economics and Statistics 82(3) 422-430.            *  
?*                                                               *
?*  This file estimates a corrected version of the model that is *
?*  described in a companion correctional note. Delete line 73   *
?*  below to replicate the published results.                    *  
?*                                                               *             
?*****************************************************************  

smpl 1 156;  ? 26 teams x 6 seasons (1986-91)

? read in team characteristics; documented in Team.doc
read(file='Team.dat') season team league attend attlag ticprice 
pmarkup gameswon gameslst wins salaries nplayers strkouts walks 
slugavg nhitters npitchrs experhit experpit nstars roadatt
aleast alcentrl alwest nleast nlcentrl nlwest;
? delete variables not used in this analysis
delete season team league gameswon gameslst nplayers strkouts walks 
slugavg nhitters npitchrs experhit experpit nstars roadatt
aleast alcentrl alwest nleast nlcentrl nlwest;

? read in city characteristics; documented in City.doc
read(file='City.dat') season team pop income white black 
hispanic landarea hincome nprfsprt;
? delete variables not used in this analysis
delete season team pop white black hispanic landarea hincome;

GENR income=income/10000;  ? SCALE INCOME                                             
GENR attend=attend/100000; ? scale attendance by same factor as
                           ? salary has been in other analysis
GENR attlag=attlag/100000;                                                          
GENR D=0;                                                                       
SMPL 1 26;          ? DEFLATE VALUES TO 1991 DOLLARS USING U.S. CPI                  
GENR income=income*135.0/109.6;                                                         
GENR salaries=salaries*135.0/109.6;                                                         
SMPL 27 52;                                                                     
GENR income=income*135.0/113.6;                                                         
GENR salaries=salaries*135.0/113.6;                                                         
SMPL 53 78;                                                                     
GENR income=income*135.0/118.3;                                                         
GENR salaries=salaries*135.0/118.3;                                                         
SMPL 79 104;                                                                    
GENR income=income*135.0/124.0;                                                         
GENR salaries=salaries*135.0/124.0;                                                         
SMPL 105 130;                                                                   
GENR income=income*135.0/130.7;                                                         
GENR salaries=salaries*135.0/130.7;                                                         
SMPL 79 156;                                                                    
GENR D=1;                                                                       
                                                                                
SMPL 1 156;                                                                     
GENR LNA=LOG(attend);                                                                
GENR LNW=LOG(wins);                                                                
GENR LN1W=LOG(1-wins);
GENR LNP=LOG(ticprice);                                                                
GENR LNinc=LOG(income);                                                              
GENR LNalag=LOG(attlag);                                                            
GENR LNnps=LOG(nprfsprt);                                                             

? generate dependent variables of the system,
? appropriately transformed by various factors                                                                                
GENR LNA=LNA+log(2);                                                        
GENR LNP=LNP+log(2);    
? pmarkup is a factor applied to ticket prices to reflect other costs 
? of game attendance. It is an attempt (not discussed in the paper) 
? to partially quantify the alpha parameter of the model.
GENR LSC=LOG(salaries)+log(2)-LOG(pmarkup)
        -log(1-(2/156)*wins)+log(1-wins); ? this term corrects the 
        ? error of the REStat paper. Omitting it will enable                                            
        ? replication of the original published results.                                                      
PARAM theta 5 theta1 0.5 theta2 0.5 theta3 0.5 phi1 1.3 phi2 0.8;                         
PARAM B0 0.5 B1 0.5 gamma 1;        
FRML E1 LNP=theta+theta1*LNalag+theta2*LNinc+theta3*LNnps
           +phi1*LNW+phi2*LN1W-gamma;                                                         
FRML E2 LNA=theta+theta1*LNalag+theta2*LNinc+theta3*LNnps
           +phi1*LNW+phi2*LN1W;                                                                 
FRML E3 LSC=2*theta+2*theta1*LNalag+2*theta2*LNinc+2*theta3*LNnps
     +2*phi1*LNW+2*phi2*LN1W                                                    
     +LOG(SQRT((phi1*(1-wins)-phi2*wins)*(phi1*(1-wins)-phi2*wins)))
     -gamma+B0+B1*D;                                                                       
LSQ(HETERO,MAXIT=100,TOL=0.00001) E1 E2 E3;                                     
                                                                                
STOP;